【安富莱STM32F407之uCOS-III教程】第9章 μCOS-III系统移植文...

[复制链接]

baiyongbin2009 发布时间：2014-12-22 16:52

阅读主题, 点击返回1楼

赞收藏评论11 发布时间：2014-12-22 16:52

11个回答

baiyongbin2009 回答时间：2014-12-22 17:19:38

9.4.3 PendSV中断

关于PendSV中断，我们在第4章和第5章已经非常详细的讲解了，这里主要是给大家分析一下任务切换的处理过程，这个中断函数的前面有英文的注释说的非常好，大家有必要看一下。

;********************************************************************************************************
; HANDLE PendSV EXCEPTION
; void OS_CPU_PendSVHandler(void)
;
; Note(s) : 1) PendSV is used to cause a context switch. This is a recommended method for performing
; context switches with Cortex-M3. This is because the Cortex-M3 auto-saves half of the
; processor context on any exception, and restores same on return from exception. So only
; saving of R4-R11 is required and fixing up the stack pointers. Using the PendSV exception
; this way means that context saving and restoring is identical whether it is initiated from
; a thread or occurs due to an interrupt or exception.
;
; 2) Pseudo-code is:
; a) Get the process SP, if 0 then skip (goto d) the saving part (first context switch);
; b) Save remaining regs r4-r11 on process stack;
; c) Save the process SP in its TCB, OSTCBCurPtr->OSTCBStkPtr = SP;
; d) Call OSTaskSwHook();
; e) Get current high priority, OSPrioCur = OSPrioHighRdy;
; f) Get current ready thread TCB, OSTCBCurPtr = OSTCBHighRdyPtr;
; g) Get new process SP from TCB, SP = OSTCBHighRdyPtr->OSTCBStkPtr;
; h) Restore R4-R11 from new process stack;
; i) Perform exception return which will restore remaining context.
;
; 3) On entry into PendSV handler:
; a) The following have been saved on the process stack (by processor):
; xPSR, PC, LR, R12, R0-R3
; b) Processor mode is switched to Handler mode (from Thread mode)
; c) Stack is Main stack (switched from Process stack)
; d) OSTCBCurPtr points to the OS_TCB of the task to suspend
; OSTCBHighRdyPtr points to the OS_TCB of the task to resume
;
; 4) Since PendSV is set to lowest priority in the system (by OSStartHighRdy() above), we
; know that it will only be run when no other exception or interrupt is active, and
; therefore safe to assume that context being switched out was using the process stack (PSP).
;********************************************************************************************************
OS_CPU_PendSVHandler
CPSID I ; Prevent interruption during context switch
MRS R0, PSP ; PSP is process stack pointer
CBZ R0, OS_CPU_PendSVHandler_nosave ; Skip register save the first time
SUBS R0, R0, #0x20 ; Save remaining regs r4-11 on process stack
STM R0, {R4-R11}
LDR R1, =OSTCBCurPtr ; OSTCBCurPtr->OSTCBStkPtr = SP;
LDR R1, [R1]
STR R0, [R1] ; R0 is SP of process being switched out
; At this point, entire context of process has been saved
OS_CPU_PendSVHandler_nosave
PUSH {R14} ; Save LR exc_return value
LDR R0, =OSTaskSwHook ; OSTaskSwHook();
BLX R0
POP {R14}
LDR R0, =OSPrioCur ; OSPrioCur = OSPrioHighRdy;
LDR R1, =OSPrioHighRdy
LDRB R2, [R1]
STRB R2, [R0]
LDR R0, =OSTCBCurPtr ; OSTCBCurPtr = OSTCBHighRdyPtr;
LDR R1, =OSTCBHighRdyPtr
LDR R2, [R1]
STR R2, [R0]
LDR R0, [R2] ; R0 is new process SP; SP = OSTCBHighRdyPtr->StkPtr;
LDM R0, {R4-R11} ; Restore r4-11 from new process stack
ADDS R0, R0, #0x20
MSR PSP, R0 ; Load PSP with new process SP
ORR LR, LR, #0x04 ; Ensure exception return uses process stack
CPSIE I
BX LR ; Exception return will restore remaining context
END

复制代码

这里PendSV中断的主要作用就是保存当前任务的现场，恢复下一个任务的寄存器，从而切换到下一个任务中执行程序，并保证退出PendSV后使用的是PSP （任务堆栈指针）。下面先把这些汇编代码解释一下：

OS_CPU_PendSVHandler ;xPSR, PC, LR, R12, R0-R3已自动保存入栈
CPSID I ;任务切换期间需要关中断
MRS R0, PSP ;R0 = PSP
CBZ R0, OS_CPU_PendSVHandler_nosave ;如果PSP==0跳转到OS_CPU_PendSVHandler_nosave去执行在多任务
;的初始化时PSP被初始化为0，表示任务是第一次运行,不需要压栈
/********************************将当前的任务寄存器入栈*********************************************/
SUBS R0, R0, #0x20 ;R0 -= 0x20 保存R4-R11到任务堆栈共32个字节
STM R0, {R4-R11} ;压栈R4-R11
LDR R1, =OSTCBCur ;获取OSTCBCur->OSTCBStkPtr，
;OSTCBStkPtr是OSTCBCur 中的第一个变量
LDR R1, [R1] ;R1 = *R1 (R1 = OSTCBCur)
STR R0, [R1] ;*R1 = R0 (*OSTCBCur = SP)
;将当前任务的堆栈保存到自己的任务控制块
;OSTCBCur->OSTCBStkPtr = PSP
;程序运行此位置,已经保存了当前任务的寄存器。
OS_CPU_PendSVHandler_nosave
PUSH {R14} ;R14 入栈
LDR R0, =OSTaskSwHook ;OSTaskSwHook(); R0 = &OSTaskSwHook
BLX R0 ;调用OSTaskSwHook()
POP {R14} ;恢复R14
/********************************加载要执行任务的寄存器*********************************************/
LDR R0, =OSPrioCur ;R0 = &OSPrioCur
LDR R1, =OSPrioHighRdy ;R1 = &OSPrioHighRdy
LDRB R2, [R1] ;R2 = *R1
STRB R2, [R0] ;*R0 = R2
;上面这四句函数的功能就是OSPrioCur = OSPrioHighRdy
LDR R0, =OSTCBCur ;R0 = &OSTCBCur
LDR R1, =OSTCBHighRdy ;R1 = &OSTCBHighRdy
LDR R2, [R1] ;R2 = *R1
STR R2, [R0] ;*R0 = R2
;上面这四句函数的功能就是OSTCBCur = OSTCBHighRdy
LDR R0, [R2] ;R0 = *R2 也就是R0 = OSTCBHighRdy又因为SP = OSTCBHighRdy->OSTCBStkPtr
;这条指令的含义就是R0=PSP。
LDM R0, {R4-R11} ;从任务堆栈恢复R4-R11
ADDS R0, R0, #0x20 ;调整R0 += 0x20
MSR PSP, R0 ;PSP = R0
ORR LR, LR, #0x04 ; 确保LR位2为1，返回后使用进程堆栈PSP
CPSIE I ; 开中断
BX LR ; 中断返回，剩下的8个寄存器会自动的出栈。
END

复制代码

为了帮助大家更好的理解这个过程，这里举一个简单的例子：

l 第一步：开始多任务后，系统就会从咱们上面说的OSStartHighRdy进入到PendSV中断，进入中断前使用的是MSP，也就是说自动入栈的8个寄存器被压入到MSP所指向的堆栈空间。

l 第二步：进入中断后开始MSP（因为中断程序中只能使用MSP，而不能使用PSP）。由于是第一次进入执行PendSV，剩下的8个需要手动入栈的寄存器不需要执行入栈操作（为什么不需要入栈操作？因为第一次执行PendSV前的函数只是μCOS-III的初始化，而不是需要执行的任务，所以现场不需要保存）。

l 第三步：获得当前需要执行的最高优先级任务A后，程序就会从任务A的堆栈空间恢复需要手动入栈的8个寄存器R4-R11，在退出PendSV后，剩下的8个寄存器内容会自动得到恢复。由于前面初始化任务堆栈的时候，已经指定了任务的地址，所以这时就能正确的切换到任务A中。

l 第四步：当任务A被挂起或者其它的原因，系统再次进入到PendSV中断，进入中断前自动入栈的8个寄存器已经被保存到任务A的堆栈空间，进入中断后再将剩余8个需要手动入栈的8个寄存器推入任务A的堆栈空间，并保存PSP到任务A的TCB控制块，剩下执行的操作就和第三步相同了，获取另一个需要执行的高优先级任务B。初学的同学一定要不这个过程分析透，并牢记。这个过程很重要，要不任务怎么切换的都不知道。